// Pig Dice game
human = 0
computer = 0
goal = 32
print "Let's play Pig to " + goal + " points!"
while human < goal and computer < goal
// Human player's turn
print
print "Your turn! (You: " + human + " Me: " + computer + ")"
rollTotal = 0
choice = "R"
while choice != "D"
if choice == "R" then // roll!
wait
roll = ceil(rnd * 6)
if roll == 1 then
print "You roll a 1. No points for you!"
rollTotal = 0
break
end if
rollTotal = rollTotal + roll
print "You roll a " + roll + ", for a total of " + rollTotal + "."
end if
choice = input("[R]oll again, or [D]one? ")
choice = choice.upper
end while
human = human + rollTotal
print "You gain " + rollTotal + " points, and now have: " + human
if human > goal then break
// Computer's turn
print
print "My turn! (You: " + human + " Me: " + computer + ")"
rollTotal = 0
while true
wait
roll = ceil(rnd * 6)
if roll == 1 then
print "I roll a 1. Darn!"
rollTotal = 0
break
end if
rollTotal = rollTotal + roll
print "I roll a " + roll + ", for a total of " + rollTotal + "."
if rnd * 20 < rollTotal then
print "That's enough for me."
break
end if
print "I'll roll again."
end while
computer = computer + rollTotal
print "I gain " + rollTotal + " points, and now have: " + computer
end while
print
print "Final scores: You: " + human + " Me: " + computer
if human > computer then
print "You win. Well played!"
else
print "I win. Good game!"
end if